Dim fs 'As Scripting.FileSystemObject
Dim wsh 'As WScript.Shell
Dim lngNumber1 'As String
Dim strOperator 'As String
Dim lngNumber2 'As Long
Dim intReturn 'As Integer
Set fs = CreateObject("Scripting.FileSystemObject")
Set wsh = CreateObject("WScript.Shell")

'Count arguments
If Wscript.Arguments.Count <> 3 Then
	wsh.Popup "You must supply three arguments -- a number, a comparison operator, and another number:" & vbCrLf & "start /w  " & Wscript.ScriptFullName &  "  ""3456""  "">""  ""4567""" & vbCrLf & "This script will return an errorlevel of 0 if your statement is true, 1 if false, 2 if in error." & vbCrLf &  "NOTE: You must always quote the operator. You never need to quote the numbers (but you can if you want).", 20, "Error"
	Select Case Wscript.Arguments.Count
		Case 0
			'Do nothing. We already gave a good error message!
		Case 1
			wsh.Popup "The one argument you supplied was:" & vbCrLf & Wscript.Arguments(0), 5, "Error"
		Case 2
			wsh.Popup "The two arguments you supplied were:" & vbCrLf & Wscript.Arguments(0) & vbCrLf & Wscript.Arguments(1), 5, "Error"
		Case Else
			wsh.Popup "You supplied four or more arguments. Only the first four are displayed here:"  & vbCrLf & Wscript.Arguments(0) & vbCrLf & Wscript.Arguments(1) & vbCrLf & Wscript.Arguments(2) & vbCrLf & Wscript.Arguments(3), 5, "Error"
	End Select
	Wscript.Quit 2
End If

'Get arguments
lngNumber1 = Wscript.Arguments(0)
strOperator = Wscript.Arguments(1)
lngNumber2 = Wscript.Arguments(2)

'Check arguments
If Not IsNumeric(lngNumber1) Then
	wsh.Popup "The first number """ & lngNumber1 & """ is not a number", 5, "Error"
	Wscript.Quit 2
End If
If Instr("> < >= <= =", strOperator) = 0 Then
	wsh.Popup "The operator you chose """ & strOperator & """ was not one of the allowed operators:" & vbCrLf & ">   <   =   >=   <=", 5, "Error"
	Wscript.Quit 2
End If
If Not IsNumeric(lngNumber2) Then
	wsh.Popup "The second number """ & lngNumber2 & """ is not a number.", 5, "Error"
	Wscript.Quit 2
End If

'Assume a false (errorlevel 1) return. We'll change it otherwise
intReturn = 1

'See if we can change it to true (rerrorlevel 0)
Select Case strOperator
	Case ">"
		If Clng(lngNumber1) > Clng(lngNumber2) Then intReturn = 0
	Case "<"
		If Clng(lngNumber1) < Clng(lngNumber2) Then intReturn = 0	
	Case "="
		If Clng(lngNumber1) = Clng(lngNumber2) Then intReturn = 0 
	Case ">="
		If Clng(lngNumber1) >= Clng(lngNumber2) Then intReturn = 0 
	Case "<="
		If Clng(lngNumber1) <= Clng(lngNumber2) Then intReturn = 0 
	Case Else
		intReturn = 2
End Select

'All done. Return the errorlevel
Wscript.Quit intReturn